1 REM **** AUTOR UNBEKANNT!
2 REM **** (ANM. VON HARDCORE TECHNO)
100 POKE53280,0:POKE53281,0:PRINTCHR$(152);CHR$(147);
110 PRINTTAB(4);"================================="
120 PRINTTAB(4);"LOESCHEN UND SCHUETZEN VON FILES"
130 PRINTTAB(4);"================================="
140 PRINT:PRINT
150 PRINT"MIT DIESEM PROGRAMM KOENNEN FILES GE-"
160 PRINT"SCHUETZT,  GELOESCHT  UND  FREIGEGEBEN"
170 PRINT"WERDEN."
180 PRINT:PRINT
190 PRINTTAB(6);" -1- AUFLISTEN ALLER FILES":PRINT
200 PRINTTAB(6);" -2- SCHUETZEN EINES FILES":PRINT
210 PRINTTAB(6);" -3- FREIGEBEN EINES FILES":PRINT
220 PRINTTAB(6);" -4- LOESCHEN EINES FILES":PRINT
230 PRINTTAB(6);" -5- BEENDEN DES PROGRAMMS":PRINT
240 GETX$:IFX$=""ORVAL(X$)<1ORVAL(X$)>5THEN240
250 IFVAL(X$)=5THEN END
260 ONVAL(X$)GOSUB280,360,610,860
270 GOTO100
280 REM ---------------------
290 REM AUFLISTEN ALLER FILES
300 REM ---------------------
310 PRINTCHR$(147)
320 FL=1:GOSUB1190
330 PRINT:PRINT"WEITER MIT RETURN"
340 INPUTX$
350 FL=0:RETURN
360 REM ---------------------
370 REM SCHUETZEN EINES FILES
380 REM ---------------------
390 GOSUB1580
400 GOSUB1190
410 IFGF= 1 THEN460
420 PRINT"FILE NICHT GEFUNDEN!":PRINT
430 PRINT"WEITER MIT RETURN!"
440 INPUTX$:CLOSE2:CLOSE15
450 RETURN
460 PRINT#15,"B-P:"2;X*32+2
470 GET#2,X$:IFX$=""THENX$=CHR$(0)
480 FT=ASC(X$)
490 IF(FT AND 64)=0THEN510
500 PRINT"FILE IST BEREITS GESCHUETZT!":PRINT:GOTO430
510 FT=(FT OR 64)
520 PRINT#15,"B-P:"2;X*32+2
530 PRINT#2,CHR$(FT);
540 PRINT#15,"B-P:"2;0
550 PRINT#15,"U2:"2;0;TT;SS
560 CLOSE2:CLOSE15
570 PRINT"FILE GESCHUETZT!"
580 PRINT"WEITER MIT RETURN!"
590 INPUTX$
600 CLOSE2:CLOSE15:RETURN
610 REM ---------------------
620 REM FREIGEBEN EINES FILES
630 REM ---------------------
640 GOSUB1580
650 GOSUB1190
660 IFGF= 1 THEN710
670 PRINT"FILE NICHT GEFUNDEN!":PRINT
680 PRINT"WEITER MIT RETURN!"
690 INPUTX$:CLOSE2:CLOSE15
700 RETURN
710 PRINT#15,"B-P:"2;X*32+2
720 GET#2,X$:IFX$=""THENX$=CHR$(0)
730 FT=ASC(X$)
740 IF(FT AND 64)=64 THEN760
750 PRINT"FILE IST BEREITS FREIGEGEBEN!":PRINT:GOTO680
760 FT=(FT AND 255-64)
770 PRINT#15,"B-P:"2;X*32+2
780 PRINT#2,CHR$(FT);
790 PRINT#15,"B-P:"2;0
800 PRINT#15,"U2:"2;0;TT;SS
810 CLOSE2:CLOSE15
820 PRINT"FILE FREIGEGEBEN!"
830 PRINT"WEITER MIT RETURN!"
840 INPUTX$
850 RETURN
860 REM ---------------------
870 REM LOESCHEN EINES FILES
880 REM ---------------------
890 GOSUB1580
900 GOSUB1190
910 IFGF= 1 THEN960
920 PRINT"FILE NICHT GEFUNDEN!":PRINT
930 PRINT"WEITER MIT RETURN!"
940 INPUTX$:CLOSE2:CLOSE15
950 RETURN
960 PRINT#15,"B-P:"2;X*32+2
970 GET#2,X$:IFX$=""THENX$=CHR$(0)
980 FT=ASC(X$)
990 IF(FT AND 64)=0THEN1040
1000 PRINT"ACHTUNG! FILE IST GESCHUETZT!"
1010 PRINT"FREIGEBEN UND LOESCHEN (J/N)?"
1020 GETX$:IFX$=""ORX$<>"N"ANDX$<>"J"THEN1020
1030 IFX$="N"THEN1170
1040 PRINT"SICHER (J/N)?"
1050 GETX$:IFX$=""ORX$<>"N"ANDX$<>"J"THEN1050
1060 IFX$="N"THEN1170
1070 FT=(FT AND 255-64)
1080 PRINT#15,"B-P:"2;X*32+2
1090 PRINT#2,CHR$(FT);
1100 PRINT#15,"B-P:"2;0
1110 PRINT#15,"U2:"2;0;TT;SS
1120 PRINT#15,"I0:"
1130 PRINT#15,"S:"+F$
1140 PRINT"FILE GELOESCHT!"
1150 PRINT"WEITER MIT RETURN!"
1160 INPUTX$
1170 CLOSE2:CLOSE15:RETURN
1180 REM
1190 REM ------------------------
1200 REM LESEN / SUCHEN VON FILES
1210 REM ------------------------
1220 OPEN15,8,15,"I0":OPEN2,8,2,"#"
1230 PRINT#15,"U1:"2;0;18;0
1240 PRINT#15,"B-P:"2;0
1250 PRINT#15,"U2:"2;0;18;0
1260 INPUT#15,X1$
1270 IFVAL(X1$)<>26THEN1330
1280 PRINT"BITTE VOR BENUTZUNG DIESES PROGRAMMS DEN";
1290 PRINT"SCHREIBSCHUTZ ENTFERNEN!"
1300 PRINT"WEITER MIT RETURN!"
1310 INPUTX$
1320 CLOSE2:CLOSE15:RETURN
1330 T=18:S=1:TT=18:SS=1
1340 PRINT#15,"U1:"2;0;T;S
1345 TT=T:SS=S
1350 PRINT#15,"B-P:"2;0
1360 GET#2,X$:IFX$=""THENX$=CHR$(0)
1370 T=ASC(X$)
1380 GET#2,X$:IFX$=""THENX$=CHR$(0)
1390 S=ASC(X$)
1400 FORX=0TO7
1410 PRINT#15,"B-P:"2;X*32+2
1420 GET#2,X$:IFX$=""THENX$=CHR$(0)
1430 IFASC(X$)=0THEN1530
1440 PRINT#15,"B-P:"2;X*32+5
1450 FF$=""
1460 FORY=0TO15
1470 GET#2,X$:IFX$=""THENX$=CHR$(0)
1480 IFASC(X$)=160THEN 1500
1490 FF$=FF$+X$
1500 NEXTY
1510 IFFLTHENPRINTFF$:GOTO1530
1520 IFF$=FF$THENGF=1:GOTO1570
1530 NEXTX
1540 IFT<>0THEN1340
1550 CLOSE2:CLOSE15
1560 IF FL=0THENPRINT"FILENAME NICHT GEFUNDEN!":FORI=1TO2000:NEXT
1570 RETURN
1580 REM ----------------------
1590 REM EINGABE DES FILENAMENS
1600 REM ----------------------
1610 PRINT:PRINT
1620 INPUT"NAME DES FILES:";F$
1630 IFLEN(F$)<=16THEN1650
1640 PRINT"FILENAME ZU LANG!":GOTO1620
1650 GF=0:FL=0
1660 RETURN